THE LIAR PARADOX: A PROPOSED RESOLUTION

***************************************

 

Here, we formally prove:

 

   ALL(a):[a e sentences => [[a e true <=> a e false] <=> a e meaningless]]

 

Where: sentences, true, false and meaningless are sets defined as below.

 

   

Dan Christensen

March 24, 2021

 

(This formal proof was written and verified with the aid of the author's DC Proof 2.0 software available at http://www.dcproof.com )

 

 

AXIOMS

******

 

Define 3 disjoint subsets of a collection of sentences: true, false and meaningless.

 

 

true is a subset of sentences

 

1     ALL(a):[a e true => a e sentences]

      Axiom

 

false is a subset of sentences

 

2     ALL(a):[a e false => a e sentences]

      Axiom

 

meaningless is a subset of senstences

 

3     ALL(a):[a e meaningless => a e sentences]

      Axiom

 

 

Every sentence is an element of one and only one of: true, false, meaningless

 

4     ALL(a):[a e sentences => [a e true | a e false | a e meaningless]

    & ~[a e true & a e false]

    & ~[a e true & a e meaningless]

    & ~[a e false & a e meaningless]]

      Axiom

 

   

    PROOF

    *****

   

    Let x be a sentence

 

      5     x e sentences

            Premise

 

    Apply definitions of the categories: true, false and meaningless

 

      6     x e sentences => [x e true | x e false | x e meaningless]

         & ~[x e true & x e false]

         & ~[x e true & x e meaningless]

         & ~[x e false & x e meaningless]

            U Spec, 4

 

      7     [x e true | x e false | x e meaningless]

         & ~[x e true & x e false]

         & ~[x e true & x e meaningless]

         & ~[x e false & x e meaningless]

            Detach, 6, 5

 

      8     x e true | x e false | x e meaningless

            Split, 7

 

      9     ~[x e true & x e false]

            Split, 7

 

      10   ~[x e true & x e meaningless]

            Split, 7

 

      11   ~[x e false & x e meaningless]

            Split, 7

 

        

         '=>'

        

         Prove: [x e true <=> x e false] => x e meaningless

        

         Suppose sentence x is true if and only if

         it is false, as in The Liar Paradox

 

            12   x e true <=> x e false

                  Premise

 

            13   [x e true => x e false] & [x e false => x e true]

                  Iff-And, 12

 

            14   x e true => x e false

                  Split, 13

 

            15   x e false => x e true

                  Split, 13

 

            

             Prove: x is not true

            

             Suppose to the contrary...

 

                  16   x e true

                        Premise

 

                  17   x e false

                        Detach, 14, 16

 

                  18   x e true & x e false

                        Join, 16, 17

 

                  19   x e true & x e false & ~[x e true & x e false]

                        Join, 18, 9

 

         As Required:

 

            20   ~x e true

                  4 Conclusion, 16

 

            

             Prove: x is not false (by contradiction)

 

                  21   x e false

                        Premise

 

                  22   x e true

                        Detach, 15, 21

 

                  23   x e true & ~x e true

                        Join, 22, 20

 

            24   ~x e false

                  4 Conclusion, 21

 

         Prove: x is meaningless

 

            25   ~[~x e true & ~x e false] | x e meaningless

                  DeMorgan, 8

 

            26   ~~[~x e true & ~x e false] => x e meaningless

                  Imply-Or, 25

 

            27   ~x e true & ~x e false => x e meaningless

                  Rem DNeg, 26

 

            28   ~x e true & ~x e false

                  Join, 20, 24

 

            29   x e meaningless

                  Detach, 27, 28

 

    As Required:

 

      30   [x e true <=> x e false] => x e meaningless

            4 Conclusion, 12

 

        

         '<='

        

         Prove: x e meaningless => [x e true <=> x e false]

        

         Suppose...

 

            31   x e meaningless

                  Premise

 

            

             Prove: ~x e true

            

             Suppose the contrary...

 

                  32   x e true

                        Premise

 

                  33   x e true & x e meaningless

                        Join, 32, 31

 

                  34   x e true & x e meaningless

                 & ~[x e true & x e meaningless]

                        Join, 33, 10

 

         As Required:

 

            35   ~x e true

                  4 Conclusion, 32

 

            

             Prove: x e true => x e false

            

             Suppose...

 

                  36   x e true

                        Premise

 

                  37   ~x e true => x e false

                        Arb Cons, 36

 

                  38   x e false

                        Detach, 37, 35

 

         As Required:

 

            39   x e true => x e false

                  4 Conclusion, 36

 

            

             Prove: ~x e false

            

             Suppose to the contrary...

 

                  40   x e false

                        Premise

 

                  41   x e false & x e meaningless

                        Join, 40, 31

 

                  42   x e false & x e meaningless

                 & ~[x e false & x e meaningless]

                        Join, 41, 11

 

         As Required:

 

            43   ~x e false

                  4 Conclusion, 40

 

            

             Prove: x e meaningless => [x e true <=> x e false]

            

             Suppose...

 

                  44   x e false

                        Premise

 

                  45   ~x e false => x e true

                        Arb Cons, 44

 

                  46   x e true

                        Detach, 45, 43

 

         As Required:

 

            47   x e false => x e true

                  4 Conclusion, 44

 

            48   [x e true => x e false] & [x e false => x e true]

                  Join, 39, 47

 

            49   x e true <=> x e false

                  Iff-And, 48

 

    As Required:

 

      50   x e meaningless => [x e true <=> x e false]

            4 Conclusion, 31

 

      51   [[x e true <=> x e false] => x e meaningless]

         & [x e meaningless => [x e true <=> x e false]]

            Join, 30, 50

 

      52   x e true <=> x e false <=> x e meaningless

            Iff-And, 51

 

As Required:

 

53   ALL(a):[a e sentences

    => [a e true <=> a e false <=> a e meaningless]]

      4 Conclusion, 5